mirror of
https://github.com/neovim/neovim.git
synced 2024-12-20 11:15:14 -07:00
a98a6996c2
Vim runtime files based on 7.4.384 / hg changeset 7090d7f160f7
Excluding:
Amiga icons (*.info, icons/)
doc/hangulin.txt
tutor/
spell/
lang/ (only used for menu translations)
macros/maze/, macros/hanoi/, macros/life/, macros/urm/
These were used to test vi compatibility.
termcap
"Demonstration of a termcap file (for the Amiga and Archimedes)"
Helped-by: Rich Wareham <rjw57@cam.ac.uk>
Helped-by: John <john.schmidt.h@gmail.com>
Helped-by: Yann <yann@yann-salaun.com>
Helped-by: Christophe Badoit <c.badoit@lesiteimmo.com>
Helped-by: drasill <github@tof2k.com>
Helped-by: Tae Sandoval Murgan <taecilla@gmail.com>
Helped-by: Lowe Thiderman <lowe.thiderman@gmail.com>
68 lines
2.2 KiB
VimL
68 lines
2.2 KiB
VimL
" Vim filetype plugin
|
|
" Language: git commit file
|
|
" Maintainer: Tim Pope <vimNOSPAM@tpope.org>
|
|
" Last Change: 2013 May 30
|
|
|
|
" Only do this when not done yet for this buffer
|
|
if (exists("b:did_ftplugin"))
|
|
finish
|
|
endif
|
|
|
|
runtime! ftplugin/git.vim
|
|
let b:did_ftplugin = 1
|
|
|
|
setlocal nomodeline tabstop=8 formatoptions-=croq formatoptions+=tl
|
|
|
|
let b:undo_ftplugin = 'setl modeline< tabstop< formatoptions<'
|
|
|
|
if &textwidth == 0
|
|
" make sure that log messages play nice with git-log on standard terminals
|
|
setlocal textwidth=72
|
|
let b:undo_ftplugin .= "|setl tw<"
|
|
endif
|
|
|
|
if exists("g:no_gitcommit_commands") || v:version < 700
|
|
finish
|
|
endif
|
|
|
|
if !exists("b:git_dir")
|
|
let b:git_dir = expand("%:p:h")
|
|
endif
|
|
|
|
command! -bang -bar -buffer -complete=custom,s:diffcomplete -nargs=* DiffGitCached :call s:gitdiffcached(<bang>0,b:git_dir,<f-args>)
|
|
|
|
function! s:diffcomplete(A,L,P)
|
|
let args = ""
|
|
if a:P <= match(a:L." -- "," -- ")+3
|
|
let args = args . "-p\n--stat\n--shortstat\n--summary\n--patch-with-stat\n--no-renames\n-B\n-M\n-C\n"
|
|
end
|
|
if exists("b:git_dir") && a:A !~ '^-'
|
|
let tree = fnamemodify(b:git_dir,':h')
|
|
if strpart(getcwd(),0,strlen(tree)) == tree
|
|
let args = args."\n".system("git diff --cached --name-only")
|
|
endif
|
|
endif
|
|
return args
|
|
endfunction
|
|
|
|
function! s:gitdiffcached(bang,gitdir,...)
|
|
let tree = fnamemodify(a:gitdir,':h')
|
|
let name = tempname()
|
|
let git = "git"
|
|
if strpart(getcwd(),0,strlen(tree)) != tree
|
|
let git .= " --git-dir=".(exists("*shellescape") ? shellescape(a:gitdir) : '"'.a:gitdir.'"')
|
|
endif
|
|
if a:0
|
|
let extra = join(map(copy(a:000),exists("*shellescape") ? 'shellescape(v:val)' : "'\"'.v:val.'\"'"))
|
|
else
|
|
let extra = "-p --stat=".&columns
|
|
endif
|
|
call system(git." diff --cached --no-color --no-ext-diff ".extra." > ".(exists("*shellescape") ? shellescape(name) : name))
|
|
exe "pedit ".(exists("*fnameescape") ? fnameescape(name) : name)
|
|
wincmd P
|
|
let b:git_dir = a:gitdir
|
|
command! -bang -bar -buffer -complete=custom,s:diffcomplete -nargs=* DiffGitCached :call s:gitdiffcached(<bang>0,b:git_dir,<f-args>)
|
|
nnoremap <buffer> <silent> q :q<CR>
|
|
setlocal buftype=nowrite nobuflisted noswapfile nomodifiable filetype=git
|
|
endfunction
|