mirror of
https://github.com/neovim/neovim.git
synced 2024-12-24 13:15:09 -07:00
a98a6996c2
Vim runtime files based on 7.4.384 / hg changeset 7090d7f160f7
Excluding:
Amiga icons (*.info, icons/)
doc/hangulin.txt
tutor/
spell/
lang/ (only used for menu translations)
macros/maze/, macros/hanoi/, macros/life/, macros/urm/
These were used to test vi compatibility.
termcap
"Demonstration of a termcap file (for the Amiga and Archimedes)"
Helped-by: Rich Wareham <rjw57@cam.ac.uk>
Helped-by: John <john.schmidt.h@gmail.com>
Helped-by: Yann <yann@yann-salaun.com>
Helped-by: Christophe Badoit <c.badoit@lesiteimmo.com>
Helped-by: drasill <github@tof2k.com>
Helped-by: Tae Sandoval Murgan <taecilla@gmail.com>
Helped-by: Lowe Thiderman <lowe.thiderman@gmail.com>
71 lines
1.8 KiB
VimL
71 lines
1.8 KiB
VimL
" Vim filetype plugin file (GUI menu and folding)
|
|
" Language: Debian control files
|
|
" Maintainer: Debian Vim Maintainers <pkg-vim-maintainers@lists.alioth.debian.org>
|
|
" Former Maintainer: Pierre Habouzit <madcoder@debian.org>
|
|
" Last Change: 2008-03-08
|
|
" URL: http://hg.debian.org/hg/pkg-vim/vim/raw-file/tip/runtime/ftplugin/debcontrol.vim
|
|
|
|
" Do these settings once per buffer
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
let b:did_ftplugin=1
|
|
|
|
" {{{1 Local settings (do on every load)
|
|
if exists("g:debcontrol_fold_enable")
|
|
setlocal foldmethod=expr
|
|
setlocal foldexpr=DebControlFold(v:lnum)
|
|
setlocal foldtext=DebControlFoldText()
|
|
endif
|
|
setlocal textwidth=0
|
|
|
|
" Clean unloading
|
|
let b:undo_ftplugin = "setlocal tw< foldmethod< foldexpr< foldtext<"
|
|
|
|
" }}}1
|
|
|
|
" {{{1 folding
|
|
|
|
function! s:getField(f, lnum)
|
|
let line = getline(a:lnum)
|
|
let fwdsteps = 0
|
|
while line !~ '^'.a:f.':'
|
|
let fwdsteps += 1
|
|
let line = getline(a:lnum + fwdsteps)
|
|
if line == ''
|
|
return 'unknown'
|
|
endif
|
|
endwhile
|
|
return substitute(line, '^'.a:f.': *', '', '')
|
|
endfunction
|
|
|
|
function! DebControlFoldText()
|
|
if v:folddashes == '-' " debcontrol entry fold
|
|
let type = substitute(getline(v:foldstart), ':.*', '', '')
|
|
if type == 'Source'
|
|
let ftext = substitute(foldtext(), ' *Source: *', ' ', '')
|
|
return ftext . ' -- ' . s:getField('Maintainer', v:foldstart) . ' '
|
|
endif
|
|
let arch = s:getField('Architecture', v:foldstart)
|
|
let ftext = substitute(foldtext(), ' *Package: *', ' [' . arch . '] ', '')
|
|
return ftext . ': ' . s:getField('Description', v:foldstart) . ' '
|
|
endif
|
|
return foldtext()
|
|
endfunction
|
|
|
|
function! DebControlFold(l)
|
|
|
|
" This is for not merging blank lines around folds to them
|
|
if getline(a:l) =~ '^Source:'
|
|
return '>1'
|
|
endif
|
|
|
|
if getline(a:l) =~ '^Package:'
|
|
return '>1'
|
|
endif
|
|
|
|
return '='
|
|
endfunction
|
|
|
|
" }}}1
|