mirror of
https://github.com/neovim/neovim.git
synced 2024-12-20 11:15:14 -07:00
a98a6996c2
Vim runtime files based on 7.4.384 / hg changeset 7090d7f160f7
Excluding:
Amiga icons (*.info, icons/)
doc/hangulin.txt
tutor/
spell/
lang/ (only used for menu translations)
macros/maze/, macros/hanoi/, macros/life/, macros/urm/
These were used to test vi compatibility.
termcap
"Demonstration of a termcap file (for the Amiga and Archimedes)"
Helped-by: Rich Wareham <rjw57@cam.ac.uk>
Helped-by: John <john.schmidt.h@gmail.com>
Helped-by: Yann <yann@yann-salaun.com>
Helped-by: Christophe Badoit <c.badoit@lesiteimmo.com>
Helped-by: drasill <github@tof2k.com>
Helped-by: Tae Sandoval Murgan <taecilla@gmail.com>
Helped-by: Lowe Thiderman <lowe.thiderman@gmail.com>
79 lines
2.0 KiB
VimL
79 lines
2.0 KiB
VimL
" Vim indent file
|
|
" Language: VisualBasic (ft=vb) / Basic (ft=basic) / SaxBasic (ft=vb)
|
|
" Author: Johannes Zellner <johannes@zellner.org>
|
|
" Last Change: Fri, 18 Jun 2004 07:22:42 CEST
|
|
" Small update 2010 Jul 28 by Maxim Kim
|
|
|
|
if exists("b:did_indent")
|
|
finish
|
|
endif
|
|
let b:did_indent = 1
|
|
|
|
setlocal autoindent
|
|
setlocal indentexpr=VbGetIndent(v:lnum)
|
|
setlocal indentkeys&
|
|
setlocal indentkeys+==~else,=~elseif,=~end,=~wend,=~case,=~next,=~select,=~loop,<:>
|
|
|
|
let b:undo_indent = "set ai< indentexpr< indentkeys<"
|
|
|
|
" Only define the function once.
|
|
if exists("*VbGetIndent")
|
|
finish
|
|
endif
|
|
|
|
fun! VbGetIndent(lnum)
|
|
" labels and preprocessor get zero indent immediately
|
|
let this_line = getline(a:lnum)
|
|
let LABELS_OR_PREPROC = '^\s*\(\<\k\+\>:\s*$\|#.*\)'
|
|
if this_line =~? LABELS_OR_PREPROC
|
|
return 0
|
|
endif
|
|
|
|
" Find a non-blank line above the current line.
|
|
" Skip over labels and preprocessor directives.
|
|
let lnum = a:lnum
|
|
while lnum > 0
|
|
let lnum = prevnonblank(lnum - 1)
|
|
let previous_line = getline(lnum)
|
|
if previous_line !~? LABELS_OR_PREPROC
|
|
break
|
|
endif
|
|
endwhile
|
|
|
|
" Hit the start of the file, use zero indent.
|
|
if lnum == 0
|
|
return 0
|
|
endif
|
|
|
|
let ind = indent(lnum)
|
|
|
|
" Add
|
|
if previous_line =~? '^\s*\<\(begin\|\%(\%(private\|public\|friend\)\s\+\)\=\%(function\|sub\|property\)\|select\|case\|default\|if\|else\|elseif\|do\|for\|while\|enum\|with\)\>'
|
|
let ind = ind + &sw
|
|
endif
|
|
|
|
" Subtract
|
|
if this_line =~? '^\s*\<end\>\s\+\<select\>'
|
|
if previous_line !~? '^\s*\<select\>'
|
|
let ind = ind - 2 * &sw
|
|
else
|
|
" this case is for an empty 'select' -- 'end select'
|
|
" (w/o any case statements) like:
|
|
"
|
|
" select case readwrite
|
|
" end select
|
|
let ind = ind - &sw
|
|
endif
|
|
elseif this_line =~? '^\s*\<\(end\|else\|elseif\|until\|loop\|next\|wend\)\>'
|
|
let ind = ind - &sw
|
|
elseif this_line =~? '^\s*\<\(case\|default\)\>'
|
|
if previous_line !~? '^\s*\<select\>'
|
|
let ind = ind - &sw
|
|
endif
|
|
endif
|
|
|
|
return ind
|
|
endfun
|
|
|
|
" vim:sw=4
|