mirror of
https://github.com/neovim/neovim.git
synced 2024-12-29 14:41:06 -07:00
b2c3e9c72e
runtime: cleanup :Sman command via the undo_ftplugin mechanism (vim/vim#12967) Regards to @dkearns as noticed in2ac708b5489d8ef7cc43Co-authored-by: Enno <Konfekt@users.noreply.github.com>
37 lines
1.4 KiB
VimL
37 lines
1.4 KiB
VimL
" Vim filetype plugin file
|
|
" Language: systemd.unit(5)
|
|
" Keyword Lookup Support: Enno Nagel <enno.nagel+vim@gmail.com>
|
|
|
|
if !exists('b:did_ftplugin')
|
|
" Looks a lot like dosini files.
|
|
runtime! ftplugin/dosini.vim
|
|
endif
|
|
|
|
if has('unix') && executable('less')
|
|
if !has('gui_running')
|
|
command -buffer -nargs=1 Sman silent exe '!' . KeywordLookup_systemd(<q-args>) | redraw!
|
|
elseif has('terminal')
|
|
command -buffer -nargs=1 Sman silent exe 'term ' . KeywordLookup_systemd(<q-args>)
|
|
endif
|
|
if exists(':Sman') == 2
|
|
if !exists('*KeywordLookup_systemd')
|
|
function KeywordLookup_systemd(keyword) abort
|
|
let matches = matchlist(getline(search('\v^\s*\[\s*.+\s*\]\s*$', 'nbWz')), '\v^\s*\[\s*(\k+).*\]\s*$')
|
|
if len(matches) > 1
|
|
let section = matches[1]
|
|
return 'LESS= MANPAGER="less --pattern=''(^|,)\s+' . a:keyword . '=$'' --hilite-search" man ' . 'systemd.' . section
|
|
else
|
|
return 'LESS= MANPAGER="less --pattern=''(^|,)\s+' . a:keyword . '=$'' --hilite-search" man ' . 'systemd'
|
|
endif
|
|
endfunction
|
|
endif
|
|
setlocal iskeyword+=-
|
|
setlocal keywordprg=:Sman
|
|
if !exists('b:undo_ftplugin') || empty(b:undo_ftplugin)
|
|
let b:undo_ftplugin = 'setlocal keywordprg< iskeyword<'
|
|
else
|
|
let b:undo_ftplugin .= '| setlocal keywordprg< iskeyword< | sil! delc -buffer Sman'
|
|
endif
|
|
endif
|
|
endif
|