mirror of
https://github.com/neovim/neovim.git
synced 2024-12-20 03:05:11 -07:00
a98a6996c2
Vim runtime files based on 7.4.384 / hg changeset 7090d7f160f7
Excluding:
Amiga icons (*.info, icons/)
doc/hangulin.txt
tutor/
spell/
lang/ (only used for menu translations)
macros/maze/, macros/hanoi/, macros/life/, macros/urm/
These were used to test vi compatibility.
termcap
"Demonstration of a termcap file (for the Amiga and Archimedes)"
Helped-by: Rich Wareham <rjw57@cam.ac.uk>
Helped-by: John <john.schmidt.h@gmail.com>
Helped-by: Yann <yann@yann-salaun.com>
Helped-by: Christophe Badoit <c.badoit@lesiteimmo.com>
Helped-by: drasill <github@tof2k.com>
Helped-by: Tae Sandoval Murgan <taecilla@gmail.com>
Helped-by: Lowe Thiderman <lowe.thiderman@gmail.com>
68 lines
2.0 KiB
VimL
68 lines
2.0 KiB
VimL
" Vim filetype plugin file
|
|
" Language: jsp
|
|
" Maintainer: Dan Sharp <dwsharp at users dot sourceforge dot net>
|
|
" Last Changed: 20 Jan 2009
|
|
" URL: http://dwsharp.users.sourceforge.net/vim/ftplugin
|
|
|
|
if exists("b:did_ftplugin") | finish | endif
|
|
|
|
" Make sure the continuation lines below do not cause problems in
|
|
" compatibility mode.
|
|
let s:save_cpo = &cpo
|
|
set cpo-=C
|
|
|
|
" Define some defaults in case the included ftplugins don't set them.
|
|
let s:undo_ftplugin = ""
|
|
let s:browsefilter = "Java Files (*.java)\t*.java\n" .
|
|
\ "HTML Files (*.html, *.htm)\t*.html;*.htm\n" .
|
|
\ "All Files (*.*)\t*.*\n"
|
|
let s:match_words = ""
|
|
|
|
runtime! ftplugin/html.vim ftplugin/html_*.vim ftplugin/html/*.vim
|
|
unlet b:did_ftplugin
|
|
|
|
" Override our defaults if these were set by an included ftplugin.
|
|
if exists("b:undo_ftplugin")
|
|
let s:undo_ftplugin = b:undo_ftplugin
|
|
unlet b:undo_ftplugin
|
|
endif
|
|
if exists("b:browsefilter")
|
|
let s:browsefilter = b:browsefilter
|
|
unlet b:browsefilter
|
|
endif
|
|
if exists("b:match_words")
|
|
let s:match_words = b:match_words
|
|
unlet b:match_words
|
|
endif
|
|
|
|
runtime! ftplugin/java.vim ftplugin/java_*.vim ftplugin/java/*.vim
|
|
let b:did_ftplugin = 1
|
|
|
|
" Combine the new set of values with those previously included.
|
|
if exists("b:undo_ftplugin")
|
|
let s:undo_ftplugin = b:undo_ftplugin . " | " . s:undo_ftplugin
|
|
endif
|
|
if exists ("b:browsefilter")
|
|
let s:browsefilter = b:browsefilter . s:browsefilter
|
|
endif
|
|
if exists("b:match_words")
|
|
let s:match_words = b:match_words . ',' . s:match_words
|
|
endif
|
|
|
|
" Load the combined list of match_words for matchit.vim
|
|
if exists("loaded_matchit")
|
|
let b:match_words = s:match_words
|
|
endif
|
|
|
|
" Change the :browse e filter to primarily show JSP-related files.
|
|
if has("gui_win32")
|
|
let b:browsefilter="JSP Files (*.jsp)\t*.jsp\n" . s:browsefilter
|
|
endif
|
|
|
|
" Undo the stuff we changed.
|
|
let b:undo_ftplugin = "unlet! b:browsefilter b:match_words | " . s:undo_ftplugin
|
|
|
|
" Restore the saved compatibility options.
|
|
let &cpo = s:save_cpo
|
|
unlet s:save_cpo
|