mirror of
https://github.com/neovim/neovim.git
synced 2024-12-20 11:15:14 -07:00
db7fdcd0ba
Using /MT was causing issues when building luarocks, revert it, use the dynammic runtime and generate release DLLs for the dependencies. Some refactoring was required because for linking cmake looks for the import libraries (.lib) but on runtime executables we need the .dll files to be in the same folder. The DLLs are placed in the bin/ folder in order for nvim.exe to run during the build and tests. The install target installs the DLLs with the nvim binary - uses GetPrerequisites to find runtime DLLs. Some minor issues that required adjustments: - [MSVC] FindMsgpack.cmake now looks for msgpack_import.lib instead of msgpack.lib - The lua-client fails to find libuv.lib, instead it looks for uv.lib, added second copy of the file to the install command. - [MSVC] CMAKE_BUILD_TYPE affects the output paths, default to Release. Part of these changes are credited to @jasonwilliams200OK who fixed the third-party recipes to consistently use the same build type.
164 lines
5.9 KiB
CMake
164 lines
5.9 KiB
CMake
# This is not meant to be included by the top-level.
|
|
cmake_minimum_required (VERSION 2.8.7)
|
|
project(NEOVIM_DEPS)
|
|
|
|
# Point CMake at any custom modules we may ship
|
|
list(APPEND CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/cmake")
|
|
|
|
# In Windows/MSVC CMAKE_BUILD_TYPE changes the paths/linking of the build
|
|
# recipes (libuv, msgpack), make sure it is set
|
|
if(NOT CMAKE_BUILD_TYPE)
|
|
set(CMAKE_BUILD_TYPE Release)
|
|
endif()
|
|
|
|
set(DEPS_INSTALL_DIR "${CMAKE_BINARY_DIR}/usr" CACHE PATH "Dependencies install directory.")
|
|
set(DEPS_BIN_DIR "${DEPS_INSTALL_DIR}/bin" CACHE PATH "Dependencies binary install directory.")
|
|
set(DEPS_LIB_DIR "${DEPS_INSTALL_DIR}/lib" CACHE PATH "Dependencies library install directory.")
|
|
set(DEPS_BUILD_DIR "${CMAKE_BINARY_DIR}/build" CACHE PATH "Dependencies build directory.")
|
|
set(DEPS_DOWNLOAD_DIR "${DEPS_BUILD_DIR}/downloads" CACHE PATH "Dependencies download directory.")
|
|
|
|
option(USE_BUNDLED "Use bundled dependencies." ON)
|
|
|
|
option(USE_BUNDLED_JEMALLOC "Use the bundled jemalloc." ${USE_BUNDLED})
|
|
option(USE_BUNDLED_UNIBILIUM "Use the bundled unibilium." ${USE_BUNDLED})
|
|
option(USE_BUNDLED_LIBTERMKEY "Use the bundled libtermkey." ${USE_BUNDLED})
|
|
option(USE_BUNDLED_LIBVTERM "Use the bundled libvterm." ${USE_BUNDLED})
|
|
option(USE_BUNDLED_LIBUV "Use the bundled libuv." ${USE_BUNDLED})
|
|
option(USE_BUNDLED_MSGPACK "Use the bundled msgpack." ${USE_BUNDLED})
|
|
option(USE_BUNDLED_LUAJIT "Use the bundled version of luajit." ${USE_BUNDLED})
|
|
option(USE_BUNDLED_LUAROCKS "Use the bundled version of luarocks." ${USE_BUNDLED})
|
|
option(USE_BUNDLED_LUV "Use the bundled version of luv." ${USE_BUNDLED})
|
|
#XXX(tarruda): Lua is only used for debugging the functional test client, no
|
|
# build it unless explicitly requested
|
|
option(USE_BUNDLED_LUA "Use the bundled version of lua." OFF)
|
|
|
|
option(USE_EXISTING_SRC_DIR "Skip download of deps sources in case of existing source directory." OFF)
|
|
|
|
if(UNIX)
|
|
find_program(MAKE_PRG NAMES gmake make)
|
|
if(MAKE_PRG)
|
|
execute_process(
|
|
COMMAND "${MAKE_PRG}" --version
|
|
OUTPUT_VARIABLE MAKE_VERSION_INFO)
|
|
if(NOT "${OUTPUT_VARIABLE}" MATCHES ".*GNU.*")
|
|
unset(MAKE_PRG)
|
|
endif()
|
|
endif()
|
|
if(NOT MAKE_PRG)
|
|
message(FATAL_ERROR "GNU Make is required to build the dependencies.")
|
|
else()
|
|
message(STATUS "Found GNU Make at ${MAKE_PRG}")
|
|
endif()
|
|
endif()
|
|
|
|
# When using make, use the $(MAKE) variable to avoid warning about the job
|
|
# server.
|
|
if(CMAKE_GENERATOR MATCHES "Makefiles")
|
|
set(MAKE_PRG "$(MAKE)")
|
|
endif()
|
|
|
|
if(CMAKE_C_COMPILER_ARG1)
|
|
set(DEPS_C_COMPILER "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
|
|
else()
|
|
set(DEPS_C_COMPILER "${CMAKE_C_COMPILER}")
|
|
endif()
|
|
|
|
# Cross compiling: use these for dependencies built for the
|
|
# HOST system, when not crosscompiling these should be the
|
|
# same as DEPS_*. Except when targeting Unix in which case
|
|
# want all the dependencies to use the same compiler.
|
|
if(CMAKE_CROSSCOMPILING AND NOT UNIX)
|
|
set(HOSTDEPS_INSTALL_DIR "${CMAKE_BINARY_DIR}/host")
|
|
set(HOSTDEPS_BIN_DIR "${HOSTDEPS_INSTALL_DIR}/bin")
|
|
set(HOSTDEPS_LIB_DIR "${HOSTDEPS_INSTALL_DIR}/lib")
|
|
set(HOSTDEPS_C_COMPILER "${HOST_C_COMPILER}")
|
|
else()
|
|
set(HOSTDEPS_INSTALL_DIR "${DEPS_INSTALL_DIR}")
|
|
set(HOSTDEPS_BIN_DIR "${DEPS_BIN_DIR}")
|
|
set(HOSTDEPS_LIB_DIR "${DEPS_LIB_DIR}")
|
|
set(HOSTDEPS_C_COMPILER "${DEPS_C_COMPILER}")
|
|
endif()
|
|
|
|
include(ExternalProject)
|
|
|
|
set(LIBUV_URL https://github.com/libuv/libuv/archive/v1.8.0.tar.gz)
|
|
set(LIBUV_SHA256 906e1a5c673c95cb261adeacdb7308a65b4a8f7c9c50d85f3021364951fa9cde)
|
|
|
|
set(MSGPACK_URL https://github.com/msgpack/msgpack-c/archive/cpp-1.0.0.tar.gz)
|
|
set(MSGPACK_SHA256 afda64ca445203bb7092372b822bae8b2539fdcebbfc3f753f393628c2bcfe7d)
|
|
|
|
set(LUAJIT_URL https://github.com/neovim/deps/raw/master/opt/LuaJIT-2.0.4.tar.gz)
|
|
set(LUAJIT_SHA256 620fa4eb12375021bef6e4f237cbd2dd5d49e56beb414bee052c746beef1807d)
|
|
|
|
set(LUA_URL https://github.com/lua/lua/archive/5.1.5.tar.gz)
|
|
set(LUA_SHA256 1cd642c4c39778306a14e62ccddace5c7a4fb2257b0b06f43bc81cf305c7415f)
|
|
|
|
set(LUAROCKS_URL https://github.com/keplerproject/luarocks/archive/5d8a16526573b36d5b22aa74866120c998466697.tar.gz)
|
|
set(LUAROCKS_SHA256 cae709111c5701235770047dfd7169f66b82ae1c7b9b79207f9df0afb722bfd9)
|
|
|
|
set(UNIBILIUM_URL https://github.com/mauke/unibilium/archive/v1.2.0.tar.gz)
|
|
set(UNIBILIUM_SHA256 623af1099515e673abfd3cae5f2fa808a09ca55dda1c65a7b5c9424eb304ead8)
|
|
|
|
set(LIBTERMKEY_URL http://www.leonerd.org.uk/code/libtermkey/libtermkey-0.18.tar.gz)
|
|
set(LIBTERMKEY_SHA256 239746de41c845af52bb3c14055558f743292dd6c24ac26c2d6567a5a6093926)
|
|
|
|
set(LIBVTERM_URL https://github.com/neovim/libvterm/archive/a9c7c6fd20fa35e0ad3e0e98901ca12dfca9c25c.tar.gz)
|
|
set(LIBVTERM_SHA256 1a4272be91d9614dc183a503786df83b6584e4afaab7feaaa5409f841afbd796)
|
|
|
|
set(JEMALLOC_URL https://github.com/jemalloc/jemalloc/releases/download/4.2.1/jemalloc-4.2.1.tar.bz2)
|
|
set(JEMALLOC_SHA256 5630650d5c1caab95d2f0898de4fe5ab8519dc680b04963b38bb425ef6a42d57)
|
|
|
|
set(LUV_URL https://github.com/luvit/luv/archive/146f1ce4c08c3b67f604c9ee1e124b1cf5c15cf3.tar.gz)
|
|
set(LUV_SHA256 3d537f8eb9fa5adb146a083eae22af886aee324ec268e2aa0fa75f2f1c52ca7a)
|
|
|
|
if(USE_BUNDLED_UNIBILIUM)
|
|
include(BuildUnibilium)
|
|
endif()
|
|
|
|
if(USE_BUNDLED_LIBTERMKEY)
|
|
include(BuildLibtermkey)
|
|
endif()
|
|
|
|
if(USE_BUNDLED_LIBVTERM)
|
|
include(BuildLibvterm)
|
|
endif()
|
|
|
|
if(USE_BUNDLED_LIBUV)
|
|
include(BuildLibuv)
|
|
endif()
|
|
|
|
if(USE_BUNDLED_MSGPACK)
|
|
include(BuildMsgpack)
|
|
endif()
|
|
|
|
if(USE_BUNDLED_LUAJIT)
|
|
include(BuildLuajit)
|
|
endif()
|
|
|
|
if(USE_BUNDLED_LUA AND NOT CMAKE_CROSSCOMPILING)
|
|
include(BuildLua)
|
|
endif()
|
|
|
|
if(USE_BUNDLED_LUAROCKS)
|
|
include(BuildLuarocks)
|
|
endif()
|
|
|
|
if(USE_BUNDLED_JEMALLOC)
|
|
include(BuildJeMalloc)
|
|
endif()
|
|
|
|
if(USE_BUNDLED_LUV)
|
|
include(BuildLuv)
|
|
endif()
|
|
|
|
add_custom_target(clean-shared-libraries
|
|
COMMAND ${CMAKE_COMMAND}
|
|
-DREMOVE_FILE_GLOB=${DEPS_INSTALL_DIR}/lib/${CMAKE_SHARED_LIBRARY_PREFIX}*${CMAKE_SHARED_LIBRARY_SUFFIX}*
|
|
-P ${PROJECT_SOURCE_DIR}/cmake/RemoveFiles.cmake
|
|
DEPENDS ${THIRD_PARTY_DEPS}
|
|
)
|
|
|
|
add_custom_target(third-party ALL
|
|
COMMAND ${CMAKE_COMMAND} -E touch .third-party
|
|
DEPENDS clean-shared-libraries)
|