mirror of
https://github.com/neovim/neovim.git
synced 2024-12-20 03:05:11 -07:00
feffc65270
- Defined CMake checks for all headers in config.h.in
- Removed headers checks that are not used anymore:
sgtty.h sys/statfs.h libintl.h poll.h
- Added UNIX check
- Add some fatal checks
+ Check for setenv() and fail if it does not exist
since our os layer just assumes it does
+ lstat is required by os_unix.c
+ sys/wait.h is required in UNIX
- Removed entries for functions that are not being used: getcwd,
getrlimit, getwd, nanosleep, sigaltstack, getwd, sigstack, fseeko
- Replaced nearly all defines in config.h.in for functions with
compile time checks
- Add check for symbol FD_CLOEXEC
- Add check for langinfo CODESET
- HAVE_ICONV_H and HAVE_ICONV hold the expected checks but Neovim uses
USE_ICONV define to actually decide whether to enable it
- Removed checks that are no longer needed
+ USEMEMMOVE
+ _FILE_OFFSET_BITS
+ HAVE_ST_BLKSIZE
+ dlfcn.h
60 lines
1.6 KiB
CMake
60 lines
1.6 KiB
CMake
# - Try to find libintl
|
|
# Once done, this will define
|
|
#
|
|
# LibIntl_FOUND - system has libintl
|
|
# LibIntl_INCLUDE_DIRS - the libintl include directories
|
|
# LibIntl_LIBRARIES - link these to use libintl
|
|
|
|
include(CheckCSourceCompiles)
|
|
include(CheckVariableExists)
|
|
include(LibFindMacros)
|
|
|
|
# Append custom gettext path to CMAKE_PREFIX_PATH
|
|
# if installed via Mac Hombrew
|
|
if (CMAKE_HOST_APPLE)
|
|
find_program(HOMEBREW_PROG brew)
|
|
if (EXISTS ${HOMEBREW_PROG})
|
|
execute_process(COMMAND ${HOMEBREW_PROG} --prefix gettext
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
OUTPUT_VARIABLE HOMEBREW_GETTEXT_PREFIX)
|
|
list(APPEND CMAKE_PREFIX_PATH "${HOMEBREW_GETTEXT_PREFIX}")
|
|
endif()
|
|
endif()
|
|
|
|
find_path(LibIntl_INCLUDE_DIR
|
|
NAMES libintl.h
|
|
)
|
|
|
|
find_library(LibIntl_LIBRARY
|
|
NAMES intl libintl.a
|
|
)
|
|
|
|
if (LibIntl_INCLUDE_DIR)
|
|
set(CMAKE_REQUIRED_INCLUDES "${LibIntl_INCLUDE_DIR}")
|
|
endif()
|
|
|
|
# This is required because some operating systems don't have a separate
|
|
# libintl--it is built into glibc. So we only need to specify the library
|
|
# if one was actually found.
|
|
if (LibIntl_LIBRARY)
|
|
set(CMAKE_REQUIRED_LIBRARIES "${LibIntl_LIBRARY}")
|
|
endif()
|
|
|
|
check_c_source_compiles("
|
|
#include <libintl.h>
|
|
|
|
int main(int argc, char** argv) {
|
|
gettext(\"foo\");
|
|
bindtextdomain(\"foo\", \"bar\");
|
|
bind_textdomain_codeset(\"foo\", \"bar\");
|
|
textdomain(\"foo\");
|
|
}" HAVE_WORKING_LIBINTL)
|
|
|
|
if (HAVE_WORKING_LIBINTL)
|
|
check_variable_exists(_nl_msg_cat_cntr HAVE_NL_MSG_CAT_CNTR)
|
|
endif()
|
|
|
|
set(LibIntl_PROCESS_INCLUDES LibIntl_INCLUDE_DIR)
|
|
set(LibIntl_PROCESS_LIBS LibIntl_LIBRARY)
|
|
libfind_process(LibIntl)
|