mirror of
https://github.com/neovim/neovim.git
synced 2024-12-20 11:15:14 -07:00
db7fdcd0ba
Using /MT was causing issues when building luarocks, revert it, use the dynammic runtime and generate release DLLs for the dependencies. Some refactoring was required because for linking cmake looks for the import libraries (.lib) but on runtime executables we need the .dll files to be in the same folder. The DLLs are placed in the bin/ folder in order for nvim.exe to run during the build and tests. The install target installs the DLLs with the nvim binary - uses GetPrerequisites to find runtime DLLs. Some minor issues that required adjustments: - [MSVC] FindMsgpack.cmake now looks for msgpack_import.lib instead of msgpack.lib - The lua-client fails to find libuv.lib, instead it looks for uv.lib, added second copy of the file to the install command. - [MSVC] CMAKE_BUILD_TYPE affects the output paths, default to Release. Part of these changes are credited to @jasonwilliams200OK who fixed the third-party recipes to consistently use the same build type.
31 lines
999 B
CMake
31 lines
999 B
CMake
# In Windows we need to find dependency DLLs and install them along with our
|
|
# binaries. This script uses the following variables:
|
|
#
|
|
# - BINARY: The binary file whose dependencies need to be installed
|
|
# - DST: The destination path
|
|
# - CMAKE_PREFIX_PATH: A list of directories to search for dependencies
|
|
|
|
if(NOT DEFINED BINARY)
|
|
message(FATAL_ERROR "Missing required argument -DBINARY=")
|
|
endif()
|
|
if(NOT DEFINED DST)
|
|
message(FATAL_ERROR "Missing required arguments -DDST=")
|
|
endif()
|
|
if(NOT DEFINED CMAKE_PREFIX_PATH)
|
|
message(FATAL_ERROR "Missing required arguments -DCMAKE_PREFIX_PATH=")
|
|
endif()
|
|
|
|
include(GetPrerequisites)
|
|
get_prerequisites(${BINARY} DLLS 1 1 "" "${CMAKE_PREFIX_PATH}")
|
|
foreach(DLL_NAME ${DLLS})
|
|
find_program(DLL_PATH ${DLL_NAME})
|
|
if(NOT DLL_PATH)
|
|
message(FATAL_ERROR "Unable to find dependency ${DLL_NAME}")
|
|
endif()
|
|
|
|
message("Copying ${DLL_NAME} to ${DST}")
|
|
execute_process(COMMAND ${CMAKE_COMMAND} -E copy ${DLL_PATH} ${DST})
|
|
unset(DLL_PATH CACHE)
|
|
endforeach()
|
|
|