mirror of
https://github.com/neovim/neovim.git
synced 2024-12-25 13:45:15 -07:00
a98a6996c2
Vim runtime files based on 7.4.384 / hg changeset 7090d7f160f7
Excluding:
Amiga icons (*.info, icons/)
doc/hangulin.txt
tutor/
spell/
lang/ (only used for menu translations)
macros/maze/, macros/hanoi/, macros/life/, macros/urm/
These were used to test vi compatibility.
termcap
"Demonstration of a termcap file (for the Amiga and Archimedes)"
Helped-by: Rich Wareham <rjw57@cam.ac.uk>
Helped-by: John <john.schmidt.h@gmail.com>
Helped-by: Yann <yann@yann-salaun.com>
Helped-by: Christophe Badoit <c.badoit@lesiteimmo.com>
Helped-by: drasill <github@tof2k.com>
Helped-by: Tae Sandoval Murgan <taecilla@gmail.com>
Helped-by: Lowe Thiderman <lowe.thiderman@gmail.com>
83 lines
2.1 KiB
VimL
83 lines
2.1 KiB
VimL
" Vim indent file
|
|
" Language: Autoconf configure.{ac,in} file
|
|
" Maintainer: Nikolai Weibull <now@bitwi.se>
|
|
" Latest Revision: 2006-12-20
|
|
" TODO: how about nested [()]'s in one line
|
|
" what's wrong with '\\\@!'?
|
|
|
|
" Only load this indent file when no other was loaded.
|
|
if exists("b:did_indent")
|
|
finish
|
|
endif
|
|
|
|
runtime! indent/sh.vim " will set b:did_indent
|
|
|
|
setlocal indentexpr=GetConfigIndent()
|
|
setlocal indentkeys=!^F,o,O,=then,=do,=else,=elif,=esac,=fi,=fin,=fil,=done
|
|
setlocal nosmartindent
|
|
|
|
" Only define the function once.
|
|
if exists("*GetConfigIndent")
|
|
finish
|
|
endif
|
|
|
|
" get the offset (indent) of the end of the match of 'regexp' in 'line'
|
|
function s:GetOffsetOf(line, regexp)
|
|
let end = matchend(a:line, a:regexp)
|
|
let width = 0
|
|
let i = 0
|
|
while i < end
|
|
if a:line[i] != "\t"
|
|
let width = width + 1
|
|
else
|
|
let width = width + &ts - (width % &ts)
|
|
endif
|
|
let i = i + 1
|
|
endwhile
|
|
return width
|
|
endfunction
|
|
|
|
function GetConfigIndent()
|
|
" Find a non-blank line above the current line.
|
|
let lnum = prevnonblank(v:lnum - 1)
|
|
|
|
" Hit the start of the file, use zero indent.
|
|
if lnum == 0
|
|
return 0
|
|
endif
|
|
|
|
" where to put this
|
|
let ind = GetShIndent()
|
|
let line = getline(lnum)
|
|
|
|
" if previous line has unmatched, unescaped opening parentheses,
|
|
" indent to its position. TODO: not failsafe if multiple ('s
|
|
if line =~ '\\\@<!([^)]*$'
|
|
let ind = s:GetOffsetOf(line, '\\\@!(')
|
|
endif
|
|
|
|
" if previous line has unmatched opening bracket,
|
|
" indent to its position. TODO: same as above
|
|
if line =~ '\[[^]]*$'
|
|
let ind = s:GetOffsetOf(line, '\[')
|
|
endif
|
|
|
|
" if previous line had an unmatched closing parantheses,
|
|
" indent to the matching opening parantheses
|
|
if line =~ '[^(]\+\\\@<!)$'
|
|
call search(')', 'bW')
|
|
let lnum = searchpair('\\\@<!(', '', ')', 'bWn')
|
|
let ind = indent(lnum)
|
|
endif
|
|
|
|
" if previous line had an unmatched closing bracket,
|
|
" indent to the matching opening bracket
|
|
if line =~ '[^[]\+]$'
|
|
call search(']', 'bW')
|
|
let lnum = searchpair('\[', '', ']', 'bWn')
|
|
let ind = indent(lnum)
|
|
endif
|
|
|
|
return ind
|
|
endfunction
|