mirror of
https://github.com/neovim/neovim.git
synced 2024-12-19 18:55:14 -07:00
d8deb91819
runtime(sh,zsh): clear $MANPAGER in ftplugin before shelling out
Say you use Vim and set MANPAGER='vim -M +MANPAGER --not-a-term -'; then
:{Zs,S}hKeywordPrg (or K) will crap out and spew terminal garbage into
less when bash's "help" fails. This was introduced by 2f25e40b1
(runtime: configure keywordpg for some file types (vim/vim#5566), 2023-08-23)
and may be present in other files touched by that commit.
Make the "man" invocation sensible by unsetting MANPAGER in the
environment.
Note that changing MANPAGER for `:terminal` is not needed; Vim within
Vim is perfectly fine.
closes: vim/vim#14679
8d8cb45756
Co-authored-by: D. Ben Knoble <ben.knoble+github@gmail.com>
43 lines
1.5 KiB
VimL
43 lines
1.5 KiB
VimL
" Vim filetype plugin file
|
|
" Language: Zsh shell script
|
|
" Maintainer: Christian Brabandt <cb@256bit.org>
|
|
" Previous Maintainer: Nikolai Weibull <now@bitwi.se>
|
|
" Latest Revision: 2024 May 06 by Vim Project (MANPAGER=)
|
|
" License: Vim (see :h license)
|
|
" Repository: https://github.com/chrisbra/vim-zsh
|
|
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
let b:did_ftplugin = 1
|
|
|
|
let s:cpo_save = &cpo
|
|
set cpo&vim
|
|
|
|
setlocal comments=:# commentstring=#\ %s formatoptions-=t formatoptions+=croql
|
|
|
|
let b:undo_ftplugin = "setl com< cms< fo< "
|
|
|
|
if executable('zsh') && &shell !~# '/\%(nologin\|false\)$'
|
|
if !has('gui_running') && executable('less')
|
|
command! -buffer -nargs=1 ZshKeywordPrg silent exe '!MANPAGER= zsh -c "autoload -Uz run-help; run-help <args> 2>/dev/null | LESS= less"' | redraw!
|
|
elseif has('terminal')
|
|
command! -buffer -nargs=1 ZshKeywordPrg silent exe ':term zsh -c "autoload -Uz run-help; run-help <args>"'
|
|
else
|
|
command! -buffer -nargs=1 ZshKeywordPrg echo system('MANPAGER= zsh -c "autoload -Uz run-help; run-help <args> 2>/dev/null"')
|
|
endif
|
|
if !exists('current_compiler')
|
|
compiler zsh
|
|
endif
|
|
setlocal keywordprg=:ZshKeywordPrg
|
|
let b:undo_ftplugin .= 'keywordprg< | sil! delc -buffer ZshKeywordPrg'
|
|
endif
|
|
|
|
let b:match_words = '\<if\>:\<elif\>:\<else\>:\<fi\>'
|
|
\ . ',\<case\>:^\s*([^)]*):\<esac\>'
|
|
\ . ',\<\%(select\|while\|until\|repeat\|for\%(each\)\=\)\>:\<done\>'
|
|
let b:match_skip = 's:comment\|string\|heredoc\|subst'
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|