03c11eb3b1
-----BEGIN PGP SIGNATURE----- iQFSBAABCAA8FiEEq68RxlopcLEwq+PEeb4+QwBBGIYFAmXJK4UeHHRvcnZhbGRz QGxpbnV4LWZvdW5kYXRpb24ub3JnAAoJEHm+PkMAQRiGHsYH/jKmzKXDRsBCcw/Q HGUvFtpohWBOpN6efdf0nxilQisuyQrqKB9fnwvfcdE60VpqMJXFMdlFh/fonxPl JMbpk9y5uw48IJZA43NwTxUrjZ4wyWzv4ZF6YWa+5WdTAJpPLEPhhnLxcHOKklMr 5Cm/7B/M7eB2BXBfc45b1pkKN22q9OXvjaKxZ+5wYmiMxS+GC8l8jiJ/WlHX78PR eLgsa1v732f2D7YF75wVhaoYepR+QzA9wTKqhjMNCEaVc2PQhA2JRsBXEt84qEIa FZigmf7LLc4ed9YA2XjRBZhAehe3cZVJZ1lasW37IATS921La2WfKuiysICJOtyT bGjK8tk= =Pt7W -----END PGP SIGNATURE----- Merge tag 'v6.8-rc4' into x86/percpu, to resolve conflicts and refresh the branch Conflicts: arch/x86/include/asm/percpu.h arch/x86/include/asm/text-patching.h Signed-off-by: Ingo Molnar <mingo@kernel.org>
98 lines
1.5 KiB
ArmAsm
98 lines
1.5 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-only */
|
|
|
|
#include <linux/export.h>
|
|
#include <linux/linkage.h>
|
|
#include <asm/percpu.h>
|
|
#include <asm/processor-flags.h>
|
|
|
|
.text
|
|
|
|
#ifndef CONFIG_X86_CMPXCHG64
|
|
|
|
/*
|
|
* Emulate 'cmpxchg8b (%esi)' on UP
|
|
*
|
|
* Inputs:
|
|
* %esi : memory location to compare
|
|
* %eax : low 32 bits of old value
|
|
* %edx : high 32 bits of old value
|
|
* %ebx : low 32 bits of new value
|
|
* %ecx : high 32 bits of new value
|
|
*/
|
|
SYM_FUNC_START(cmpxchg8b_emu)
|
|
|
|
pushfl
|
|
cli
|
|
|
|
cmpl (%esi), %eax
|
|
jne .Lnot_same
|
|
cmpl 4(%esi), %edx
|
|
jne .Lnot_same
|
|
|
|
movl %ebx, (%esi)
|
|
movl %ecx, 4(%esi)
|
|
|
|
orl $X86_EFLAGS_ZF, (%esp)
|
|
|
|
popfl
|
|
RET
|
|
|
|
.Lnot_same:
|
|
movl (%esi), %eax
|
|
movl 4(%esi), %edx
|
|
|
|
andl $(~X86_EFLAGS_ZF), (%esp)
|
|
|
|
popfl
|
|
RET
|
|
|
|
SYM_FUNC_END(cmpxchg8b_emu)
|
|
EXPORT_SYMBOL(cmpxchg8b_emu)
|
|
|
|
#endif
|
|
|
|
#ifndef CONFIG_UML
|
|
|
|
/*
|
|
* Emulate 'cmpxchg8b %fs:(%rsi)'
|
|
*
|
|
* Inputs:
|
|
* %esi : memory location to compare
|
|
* %eax : low 32 bits of old value
|
|
* %edx : high 32 bits of old value
|
|
* %ebx : low 32 bits of new value
|
|
* %ecx : high 32 bits of new value
|
|
*
|
|
* Notably this is not LOCK prefixed and is not safe against NMIs
|
|
*/
|
|
SYM_FUNC_START(this_cpu_cmpxchg8b_emu)
|
|
|
|
pushfl
|
|
cli
|
|
|
|
cmpl __percpu (%esi), %eax
|
|
jne .Lnot_same2
|
|
cmpl __percpu 4(%esi), %edx
|
|
jne .Lnot_same2
|
|
|
|
movl %ebx, __percpu (%esi)
|
|
movl %ecx, __percpu 4(%esi)
|
|
|
|
orl $X86_EFLAGS_ZF, (%esp)
|
|
|
|
popfl
|
|
RET
|
|
|
|
.Lnot_same2:
|
|
movl __percpu (%esi), %eax
|
|
movl __percpu 4(%esi), %edx
|
|
|
|
andl $(~X86_EFLAGS_ZF), (%esp)
|
|
|
|
popfl
|
|
RET
|
|
|
|
SYM_FUNC_END(this_cpu_cmpxchg8b_emu)
|
|
|
|
#endif
|