8f8c1ff879
I believe the hardcoded 0x800 and related comments come from the long history VDSO_TEXT_OFFSET in x86 vdso code, but commit5b93049337("x86 vDSO: generate vdso-syms.lds") and commitf6b46ebf90("x86 vDSO: new layout") removes the comment and hard coding for x86. Similar as x86 and other arch, riscv doesn't need the rigid layout using VDSO_TEXT_OFFSET since it "no longer matters to the kernel". so we could remove the hard coding now, and removing it brings a small vdso.so and aligns with other architectures. Also, having enough separation between data and text is important for I-cache, so similar as x86, move .note, .eh_frame_hdr, and .eh_frame between .rodata and .text. Signed-off-by: Jisheng Zhang <jszhang@kernel.org> Reviewed-by: Andrew Jones <ajones@ventanamicro.com> Tested-by: Emil Renner Berthing <emil.renner.berthing@canonical.com> Link: https://lore.kernel.org/r/20230912072015.2424-4-jszhang@kernel.org Signed-off-by: Palmer Dabbelt <palmer@rivosinc.com>
87 lines
1.8 KiB
ArmAsm
87 lines
1.8 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-only */
|
|
/*
|
|
* Copyright (C) 2012 Regents of the University of California
|
|
*/
|
|
#include <asm/page.h>
|
|
#include <asm/vdso.h>
|
|
|
|
OUTPUT_ARCH(riscv)
|
|
|
|
SECTIONS
|
|
{
|
|
PROVIDE(_vdso_data = . - __VVAR_PAGES * PAGE_SIZE);
|
|
#ifdef CONFIG_TIME_NS
|
|
PROVIDE(_timens_data = _vdso_data + PAGE_SIZE);
|
|
#endif
|
|
. = SIZEOF_HEADERS;
|
|
|
|
.hash : { *(.hash) } :text
|
|
.gnu.hash : { *(.gnu.hash) }
|
|
.dynsym : { *(.dynsym) }
|
|
.dynstr : { *(.dynstr) }
|
|
.gnu.version : { *(.gnu.version) }
|
|
.gnu.version_d : { *(.gnu.version_d) }
|
|
.gnu.version_r : { *(.gnu.version_r) }
|
|
|
|
.dynamic : { *(.dynamic) } :text :dynamic
|
|
|
|
.rodata : {
|
|
*(.rodata .rodata.* .gnu.linkonce.r.*)
|
|
*(.got.plt) *(.got)
|
|
*(.data .data.* .gnu.linkonce.d.*)
|
|
*(.dynbss)
|
|
*(.bss .bss.* .gnu.linkonce.b.*)
|
|
}
|
|
|
|
.note : { *(.note.*) } :text :note
|
|
|
|
.eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr
|
|
.eh_frame : { KEEP (*(.eh_frame)) } :text
|
|
|
|
/*
|
|
* Text is well-separated from actual data: there's plenty of
|
|
* stuff that isn't used at runtime in between.
|
|
*/
|
|
. = ALIGN(16);
|
|
.text : { *(.text .text.*) } :text
|
|
|
|
. = ALIGN(4);
|
|
.alternative : {
|
|
*(.alternative)
|
|
}
|
|
}
|
|
|
|
/*
|
|
* We must supply the ELF program headers explicitly to get just one
|
|
* PT_LOAD segment, and set the flags explicitly to make segments read-only.
|
|
*/
|
|
PHDRS
|
|
{
|
|
text PT_LOAD FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
|
|
dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
|
|
note PT_NOTE FLAGS(4); /* PF_R */
|
|
eh_frame_hdr PT_GNU_EH_FRAME;
|
|
}
|
|
|
|
/*
|
|
* This controls what symbols we export from the DSO.
|
|
*/
|
|
VERSION
|
|
{
|
|
LINUX_4.15 {
|
|
global:
|
|
__vdso_rt_sigreturn;
|
|
#ifdef HAS_VGETTIMEOFDAY
|
|
__vdso_gettimeofday;
|
|
__vdso_clock_gettime;
|
|
__vdso_clock_getres;
|
|
#endif
|
|
__vdso_getcpu;
|
|
__vdso_flush_icache;
|
|
#ifndef COMPAT_VDSO
|
|
__vdso_riscv_hwprobe;
|
|
#endif
|
|
local: *;
|
|
};
|
|
}
|